pxCreateHull%(vbank*, nvert%,mass#)

Параметры

vbank* - указатель на массив вершин
nvert% - количество вершин
mass# - масса тела

Описание

Создает тело с выпуклой геометрией, задаваемой набором вершин. vbank* - банк с координатами всех вершин, nvert% - число вершин. Возвращает идентификатор тела.
Ограничение: - нельзя превышать 256 полигонов или 512 треугольников.
Внимание - если mass = 0 тело статическое, при прочих значениях динамическое.

Смотрите так же

Пример

;Пример использования функции
;pxCreateHull

Graphics3D 800,600,32,2

cam = CreateCamera()
PositionEntity cam,0,6,-20

light = CreateLight()
RotateEntity light,20,30,40

hull_mesh = LoadMesh("media\camel.x")
ScaleMesh hull_mesh ,3,3,3

pxCreateWorld(0)

plane_body = PxCreateCube(5,0.5,7.5,0)
;визуализируем его
plane_mesh=CreateCube()
ScaleEntity(plane_mesh,5,0.5,7.5)

;подготавливамем данные для тела геометрией hull
nsurf = CountSurfaces(hull_mesh)
nvert = 0
;подсчтываем количество вертексов
For ns = 1 To nsurf
    Local surf = GetSurface(hull_mesh,ns)
    nvert = nvert + CountVertices(surf)
Next

;создаем массив вертексов
vbank = CreateBank(nvert*4*3)
nv = 0

;заполняем массив данными
For ns = 1 To nsurf
    surf = GetSurface(hull_mesh,ns)
    nvv = CountVertices(surf)
    For nvc = 0 To nvv - 1
        PokeFloat vbank,nv*12+0,VertexX(surf,nvc)
        PokeFloat vbank,nv*12+4,VertexY(surf,nvc)
        PokeFloat vbank,nv*12+8,VertexZ(surf,nvc)
        nv = nv+1
    Next
Next

; -------------- Применяем pxCreateHull
;создаем тело
hull_body = pxCreateHull(vbank,nvert,10)

FreeBank vbank

pxSetPosition hull_body,2,20,-2 ; Устанавливем в позицию
pxSetRotation hull_body,0,-45,0 ;Вращаем

While Not(KeyHit(1))

;обсчитываем физический мир
    RenderPhysic(70,1)

;ставим визуальное тело в позицию физического тела
    pxSetEntity hull_mesh, hull_body

    RenderWorld
    Flip
Wend
End

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.